1с как найти значение в дереве значений

Объект «ДеревоЗначений» в 1С 8.3 представляет собой динамический набор значений любого типа. Для такого набора доступны свойства «колонки» и «строки» где каждая строка может иметь набор подчинённых строк, а каждая подчинённая строка набор своих подчинённых строк и т.д.  Программная инициализация дерева значений в 1С осуществляется с помощью оператора НОВЫЙ.

Пример:

ДеревоЗначений = Новый ДеревоЗначений;

Визуально, объект «ДеревоЗначений» похож на дерево групп справочника. К примеру, можно открыть справочник «Номенклатура» любой типовой конфигурации выставив форму списка в «Режим просмотра» — «Дерево».

Полезно понимать, что объект «ДеревоЗначений» схож с объектом «ТаблицаЗначений». Основной отличительный признак наличие дополнительного реквизита «Родитель» у объекта «ДеревоЗначений», с помощью которого и организовывается иерархия и подчинённость.

Дерево значений на управляемой форме

Если появляется необходимость показать данные в виде дерева пользователю, следует на форме создать реквизит с типом «ДеревоЗначений» и определится с составом колонок.

Для отображения на форме добавим реквизит в раздел элементов формы простым перетаскиванием.

Заполнение дерева значений

Заполнить данными дерево значений в 1С можно программно (вручную) или получить из результата запроса. Рассмотрим на примерах оба способа.

Ручное заполнение реквизита формы с типом «ДеревоЗначений»

Простой пример:

&НаКлиенте
Процедура ДЗ_НаФорме(Команда)
ДЗ_НаФормеНаСервере();
КонецПроцедуры

&НаСервере
Процедура ДЗ_НаФормеНаСервере()

// Преобразуем реквизит формы ДЗ в объект прикладного типа
ДеревоЗначений = РеквизитФормыВЗначение("ДЗ");

Корень = ДеревоЗначений.Строки.Добавить();
Корень.Наименование = "Корневая группа";

Группа1 = Корень.Строки.Добавить();
Группа1.Наименование = "Первая группа";

Элемент1 = Группа1.Строки.Добавить();
Элемент1.Наименование = "Элемент №1";                               

Группа2 = Корень.Строки.Добавить();
Группа2.Наименование = "Втровая группа";

Элемент1 = Группа2.Строки.Добавить();
Элемент1.Наименование = "Элемент №1";

Элемент2 = Группа2.Строки.Добавить();
Элемент2.Наименование = "Элемент №2";
        
// Преобразуем объект ДеревоЗначений в реквизит формы         
ЗначениеВРеквизитФормы(ДеревоЗначений,"ДЗ");                                                                     

КонецПроцедуры

Результат запроса на форме:

Заполнение дерева значений из результата запроса

Сделаем простой запрос к справочнику «Номенклатура». Результат запроса преобразуем в дерево значений с помощью метода «Выгрузить», установив для его параметра «ТипОбхода» в значение «ПоГруппировкамСИерархией».  Для передачи сформированного дерева значений на форму, важно чтобы имена колонок совпадали с именами колонок реквизита на форме.

&НаКлиенте
Процедура ДЗ_НаФорме(Команда)
ДЗ_НаФормеНаСервере();
КонецПроцедуры

&НаСервере
Процедура ДЗ_НаФормеНаСервере()

Запрос = Новый Запрос;
Запрос.Текст =
"ВЫБРАТЬ
|          Номенклатура.Ссылка КАК Наименование
|ИЗ
|          Справочник.Номенклатура КАК Номенклатура
|
|УПОРЯДОЧИТЬ ПО
|          Наименование ИЕРАРХИЯ";
ДеревоЗначений = Запрос.Выполнить().Выгрузить(ОбходРезультатаЗапроса.ПоГруппировкамСИерархией);

ЗначениеВРеквизитФормы(ДеревоЗначений, "ДЗ");

КонецПроцедуры

Результат запроса на форме может выглядеть так:

Поиск строк в дереве значений

Для поиска строк в дереве значений существует два способа, точнее говоря, метода.

Метод «Найти()»

• Найти(<Значение>, <Колонки>, <ВключатьПодчиненные>)

Возвращает строку дерева значений, если строка не найдена, вернёт «Неопределено». Поиск можно ограничивать, указав в параметре <Колонки> нужные колонки для поиска. Также расширять, указав для параметра <ВключатьПодчиненные> значение «Истина», тогда в поиске будут участвовать строки подчинённых коллекций.

Для примера найдём строку со значением «Элемент №1» в дереве значений вида:

Пример кода:

&НаКлиенте
Процедура НайтиСтрокуДЗ(Команда)
            НайтиСтрокуДЗ_НаСервере();
КонецПроцедуры

&НаСервере
Процедура НайтиСтрокуДЗ_НаСервере()

// Преобразуем реквизит формы ДЗ в объект прикладного типа
ДеревоЗначений = РеквизитФормыВЗначение("ДЗ");

// Ищем строку
НайденнаяСтрока = ДеревоЗначений.Строки.Найти("Элемент №1","Наименование", Истина);

// Анализ результата поиска
Если НайденнаяСтрока = Неопределено Тогда
Сообщить("Строка не найдена");
Иначе
Сообщить(НайденнаяСтрока.Наименование + " - " + НайденнаяСтрока.Родитель.Наименование);
КонецЕсли;
          
КонецПроцедуры

Результат:

Из результата видно, что метод вернул первую попавшуюся строку, и поиск был прекращён.

Метод «НайтиСтроки()»

Если необходимо найти все строки со значением «Элемент №1» тогда следует использовать метод НайтиСтроки()

• НайтиСтроки(<ПараметрыОтбора>, <ВключатьПодчиненные>)

Где <ПараметрыОтбора> — это условия для поиска в виде структуры, а параметр <ВключатьПодчиненные> с помощью значений Ложь/Истина контролирует возможность поиска в подчинённых коллекциях.

Пример кода:

&НаКлиенте
Процедура НайтиСтрокиДЗ(Команда)
НайтиСтрокиДЗНаСервере();
КонецПроцедуры

&НаСервере
Процедура НайтиСтрокиДЗНаСервере()

// Преобразуем реквизит формы ДЗ в объект прикладного типа
ДеревоЗначений = РеквизитФормыВЗначение("ДЗ");

// Условие для поиска
ПараметрыОтбора = Новый Структура;
ПараметрыОтбора.Вставить("Наименование", "Элемент №1");

// Поиск строк
МассивСтрок = ДеревоЗначений.Строки.НайтиСтроки(ПараметрыОтбора, Истина);

// Проверяем найдены ли строки
Если МассивСтрок.Количество() = 0 Тогда
Сообщить("Не найдено ни одной строки, удовлетворяющей условия поиска.");
КонецЕсли;

// Перебор массива строк
Для Каждого Строка Из МассивСтрок Цикл

Если Строка.Родитель = Неопределено Тогда
Сообщить(Строка.Наименование + " - Корень дерева значений.");
Иначе
Сообщить(Строка.Наименование + " - " + Строка.Родитель.Наименование);
КонецЕсли

КонецЦикла;

КонецПроцедуры

Результат:

Очистка дерева значений или строк

Для очистки дерева значений пригодятся методы  Очистить(), Удалить(). Пример кода:

&НаСервере
Процедура УдалитьСтрокуНаСервере()

// Преобразуем реквизит формы ДЗ в объект прикладного типа
ДеревоЗначений = РеквизитФормыВЗначение("ДЗ");

ДеревоЗначений.Строки.Очистить();

// Или по индексу
ДеревоЗначений.Строки.Удалить(0);

// Преобразуем объект ДеревоЗначений в реквизит формы
ЗначениеВРеквизитФормы(ДеревоЗначений, "ДЗ");

КонецПроцедуры

С помощью данных методов возможно удаление конкретных строк дерева значений.

!!!При удалении либо очистки строки все её подчинённые строки удалятся!!!

Обход дерева значений в 1С

Обойти все строки дерева значений удобнее всего с помощью рекурсии.  Таким способом мы сможем обойти дерево значений любой вложенности.

Пример:

&НаСервере
Процедура ОбойтиДЗ_НаСервере()
ДеревоЗначений = РеквизитФормыВЗначение("ДЗ");
ОбходДереваЗначений(ДеревоЗначений);
КонецПроцедуры

&НаСервере
Процедура ОбходДереваЗначений(Данные)

Для Каждого Строка Из Данные.Строки Цикл

Сообщить(Строка.Наименование);

Если Строка.Строки.Количество()>0 Тогда
ОбходДереваЗначений(Строка);
КонецЕсли;

КонецЦикла;

КонецПроцедуры

Как преобразовать дерево значений в таблицу значений

Состав элементов и реквизитов формы:

&НаКлиенте
Процедура ВТЗ(Команда)
ВТЗНаСервере();
КонецПроцедуры

&НаСервере
Процедура ВТЗНаСервере()


ДеревоЗначений = РеквизитФормыВЗначение("ДЗ");
ТаблицаЗначений = РеквизитФормыВЗначение("ТЗ");

ПреобразоватьВ_ТЗ(ДеревоЗначений, ТаблицаЗначений, Новый УникальныйИдентификатор("00000000-0000-0000-0000-000000000000"));
ДеревоЗначений.Строки.Очистить();

ЗначениеВРеквизитФормы(ТаблицаЗначений, "ТЗ");
ЗначениеВРеквизитФормы(ДеревоЗначений, "ДЗ");
КонецПроцедуры

&НаСервере
Процедура ПреобразоватьВ_ТЗ(Данные, ТаблицаЗначений, ГУИД)

Для Каждого Строка Из Данные.Строки Цикл

НовСтрока = ТаблицаЗначений.Добавить();
НовСтрока.Наименование = Строка.Наименование;
НовСтрока.Родитель = ГУИД;
НовСтрока.ГУИД = Новый УникальныйИдентификатор();

Если Строка.Строки.Количество()>0 Тогда
ПреобразоватьВ_ТЗ(Строка, ТаблицаЗначений, НовСтрока.ГУИД);
КонецЕсли;

КонецЦикла;

КонецПроцедуры

Используя данный способ можно легко преобразовать таблицу значений обратно в дерево значений.  Из примера «ГУИД» это уникальный идентификатор строки, а «Родитель» уникальный идентификатор родителя. Если обратного преобразования не требуется можно исключить использование колонок «Родитель» и  «ГУИД».

Дерево значений представляет из себя некую структуру с иерархией. Каждая строка имеет свойства «Родитель» и «Строки». У каждой строки может быть сколько угодно подчиненных строк. При этом такие операции как поиск, сортировка, подсчет итогов можно проводить с учетом уровня иерархии и подчиненных строк.

Программное создание дерева значений

Как уже упоминалось выше, каждая строка имеет свойство Строки, которое содержит коллекцию дочерних строк. И сам объект ДеревоЗначений имеет свойство Строки, которое содержит коллекцию строк верхнего уровня.

&НаКлиенте
Процедура СоздатьДеревоЗначений(Команда)
    СоздатьДеревоЗначенийНаСервере();
КонецПроцедуры

&НаСервере
Процедура СоздатьДеревоЗначенийНаСервере()

    // создаем объект ДеревоЗначений и добавляем колонки
    ДеревоЗначений = Новый ДеревоЗначений();
    ДеревоЗначений.Колонки.Добавить("Код");
    ДеревоЗначений.Колонки.Добавить("Наименование");
    ДеревоЗначений.Колонки.Добавить("Количество");

    // добавляем две строки верхнего уровня
    ГруппаТовары = ДеревоЗначений.Строки.Добавить();
    ГруппаТовары.Код = "001";
    ГруппаТовары.Наименование = "Товары";
    ГруппаТовары.Количество = "";
    ГруппаУслуги = ДеревоЗначений.Строки.Добавить();
    ГруппаУслуги.Код = "002";
    ГруппаУслуги.Наименование = "Услуги";
    ГруппаУслуги.Количество = "";

    // для первой строки верхнего уровня добавляем дочерние строки
    ПервыйТовар = ГруппаТовары.Строки.Добавить();
    ПервыйТовар.Код = "003";
    ПервыйТовар.Наименование = "Первый товар";
    ПервыйТовар.Количество = 5;
    ПервыйТовар = ГруппаТовары.Строки.Добавить();
    ПервыйТовар.Код = "004";
    ПервыйТовар.Наименование = "Второй товар";
    ПервыйТовар.Количество = 7;

    // для второй строки верхнего уровня добавляем дочерние строки
    ПерваяУслуга = ГруппаУслуги.Строки.Добавить();
    ПерваяУслуга.Код = "005";
    ПерваяУслуга.Наименование = "Первая услуга";
    ПерваяУслуга.Количество = "";
    ВтораяУслуга = ГруппаУслуги.Строки.Добавить();
    ВтораяУслуга.Код = "006";
    ВтораяУслуга.Наименование = "Вторая услуга";
    ВтораяУслуга.Количество = "";

    // цикл по строкам верхнего уровня
    Для Каждого ТекущаяГруппа Из ДеревоЗначений.Строки Цикл
        Сообщить("Код: " + ТекущаяГруппа.Код + ", Группа: " + ТекущаяГруппа.Наименование);
        // цикл по дочерним строкам текущей строки верхнего уровня
        Для Каждого ТекущийТоварИлиУслуга Из ТекущаяГруппа.Строки Цикл
            Сообщить(
                "Код: " + ТекущийТоварИлиУслуга.Код +
                ", Товар или услуга: " + ТекущийТоварИлиУслуга.Наименование
            );
        КонецЦикла;
    КонецЦикла;

КонецПроцедуры

Код: 001, Группа: Товары
Код: 003, Товар или услуга: Первый товар
Код: 004, Товар или услуга: Второй товар
Код: 002, Группа: Услуги
Код: 005, Товар или услуга: Первая услуга
Код: 006, Товар или услуга: Вторая услуга

КоллекцияКолонокДереваЗначений.Добавить(Имя, Тип, Заголовок, Ширина) 

КоллекцияСтрокДереваЗначений.Добавить()

Заполнить табличное поле на форме

Визуальное представление дерева значений на форме обеспечивает элемент Таблица.

Пример программного заполнения дерева значений для управляемых форм:

&НаКлиенте
Процедура ЗаполнитьТабличноеПоле(Команда)
    ЗаполнитьТабличноеПолеНаСервере();
КонецПроцедуры

&НаСервере
Процедура ЗаполнитьТабличноеПолеНаСервере()
    ДеревоЗначений = РеквизитФормыВЗначение("РеквизитДеревоЗначений");

    // Добавляем строку в корень дерева
    ПерваяСтрока = ДеревоЗначений.Строки.Добавить();
    ПерваяСтрока.ПерваяКолонка = "Первая строка, первая колонка";
    ПерваяСтрока.ВтораяКолонка = "Первая строка, вторая колонка";
    // Дочерняя строка первой строки
    ВтораяСтрока = ПерваяСтрока.Строки.Добавить();
    ВтораяСтрока.ПерваяКолонка = "Вторая строка, первая колонка";
    ВтораяСтрока.ВтораяКолонка = "Вторая строка, вторая колонка";
    // Дочерняя строка второй строки
    ТретьяСтрока = ВтораяСтрока.Строки.Добавить();
    ТретьяСтрока.ПерваяКолонка = "Третья строка, первая колонка";
    ТретьяСтрока.ВтораяКолонка = "Третья строка, вторая колонка";

    ЗначениеВРеквизитФормы(ДеревоЗначений, "РеквизитДеревоЗначений");
КонецПроцедуры

Результат выполнения запроса очень легко преобразовать в дерево значений, для этого нужно воспользоваться методом Выгрузить() и указать параметр ТипОбхода отличным от того, что стоит по умолчанию, т.е. ПоГруппировкам или ПоГруппировкамСИерархией.

&НаКлиенте
Процедура ЗаполнитьТабличноеПоле(Команда)
    ЗаполнитьТабличноеПолеНаСервере();
КонецПроцедуры

&НаСервере
Процедура ЗаполнитьТабличноеПолеНаСервере()
    Запрос = Новый Запрос();
    Запрос.Текст = 
        "ВЫБРАТЬ
        |    Номенклатура.Наименование КАК ПерваяКолонка,
        |    Номенклатура.Код КАК ВтораяКолонка
        |ИЗ
        |    Справочник.Номенклатура КАК Номенклатура
        |УПОРЯДОЧИТЬ ПО
        |    ПерваяКолонка ИЕРАРХИЯ";
    ДеревоЗначений = Запрос.Выполнить().Выгрузить(
        ОбходРезультатаЗапроса.ПоГруппировкамСИерархией
    );
    ЗначениеВРеквизитФормы(ДеревоЗначений, "РеквизитДеревоЗначений"); 
КонецПроцедуры

Свернуть и развернуть строки дерева значений

Свернуть и развернуть дочерние строки элемента дерева значений можно с помощью методов Свернуть() и Развернуть().

ВсеЭлементыФормы.ЭлементТаблицаФормы.Свернуть(ИдектификаторСтроки)

• Сворачивает узел в указанной строке дерева.
• ИдектификаторСтроки — идентификатор строки таблицы.

ВсеЭлементыФормы.ЭлементТаблицаФормы.Развернуть(ИдектификаторСтроки, СПодчиненными)

• Разворачивает узел в указанной строке дерева.
• ИдектификаторСтроки — идентификатор строки таблицы.
• СПодчиненными — определяет необходимость раскрытия подчиненных узлов.

&НаКлиенте
Процедура СвернутьТекущуюСтрокуДерева(Команда)
    Элементы.ЭлементДеревоЗначений.Свернуть(
        Элементы.ЭлементДеревоЗначений.ТекущаяСтрока
    );
КонецПроцедуры

&НаКлиенте
Процедура СвернутьВерхниеСтрокиДерева(Команда)
    СтрокиДерева = РеквизитДеревоЗначений.ПолучитьЭлементы();
    Для Каждого ТекущаяСтрока Из СтрокиДерева Цикл
        Элементы.ЭлементДеревоЗначений.Свернуть(
            ТекущаяСтрока.ПолучитьИдентификатор()
        );
    КонецЦикла;
КонецПроцедуры

&НаКлиенте
Процедура СвернутьВсеСтрокиДерева(Команда)
    СтрокиДерева = РеквизитДеревоЗначений.ПолучитьЭлементы();
    СвернутьДочерниеСтрокиДерева(СтрокиДерева); 
КонецПроцедуры
 
&НаКлиенте
Процедура СвернутьДочерниеСтрокиДерева(СтрокиДерева)
    Для Каждого ТекущаяСтрока Из СтрокиДерева Цикл
        ДочерниеСтроки = ТекущаяСтрока.ПолучитьЭлементы();
        // рекурсивный вызов процедуры СвернутьДочерниеСтрокиДерева()
        СвернутьДочерниеСтрокиДерева(ДочерниеСтроки);
        Элементы.ЭлементДеревоЗначений.Свернуть(
            ТекущаяСтрока.ПолучитьИдентификатор()
        );
    КонецЦикла; 
КонецПроцедуры

&НаКлиенте
Процедура РазвернутьТекущуюСтрокуДерева(Команда)
    Элементы.ЭлементДеревоЗначений.Развернуть(
        Элементы.ЭлементДеревоЗначений.ТекущаяСтрока, Истина
    );
КонецПроцедуры

&НаКлиенте
Процедура РазвернутьВсеСтрокиДерева(Команда)
    СтрокиДерева = РеквизитДеревоЗначений.ПолучитьЭлементы();
    Для Каждого ТекущаяСтрока Из СтрокиДерева Цикл
        Элементы.ЭлементДеревоЗначений.Развернуть(
            ТекущаяСтрока.ПолучитьИдентификатор(), Истина
        );
    КонецЦикла;
КонецПроцедуры

ДанныеФормыДерево.ПолучитьЭлементы()

ДанныеФормыЭлементДерева.ПолучитьЭлементы()

Удалить строку и очистить дерево значений

&НаКлиенте
Процедура УдалитьСтрокуДереваЗначений(Команда)
    УдалитьСтрокуДереваЗначенийНаСервере();
КонецПроцедуры

&НаСервере
Процедура УдалитьСтрокуДереваЗначенийНаСервере()
    ДеревоЗначений = РеквизитФормыВЗначение("РеквизитДеревоЗначений");
    // удаляем первую строку дерева значений
    ДеревоЗначений.Строки.Удалить(0);
    ЗначениеВРеквизитФормы(ДеревоЗначений, "РеквизитДеревоЗначений");
КонецПроцедуры

&НаКлиенте
Процедура ОчиститьДеревоЗначений(Команда)
    ОчиститьДеревоЗначенийНаСервере();
КонецПроцедуры

&НаСервере
Процедура ОчиститьДеревоЗначенийНаСервере()
    ДеревоЗначений = РеквизитФормыВЗначение("РеквизитДеревоЗначений");
    ДеревоЗначений.Строки.Очистить();
    ЗначениеВРеквизитФормы(ДеревоЗначений, "РеквизитДеревоЗначений");
КонецПроцедуры

Поиск в дереве значений

Среди наиболее часто используемых методов стоит отметить метод Найти() коллекции строк дерева значений.

КоллекцияСтрокДереваЗначений.Найти(Значение, Колонки, ВключатьПодчиненные)

• Значение (обязательный, тип Произвольный). Искомое значение.
• Колонки (необязательный, тип Строка). Список имен колонок, в которых будет осуществляться поиск, разделенных запятыми. Если параметр не указан, поиск осуществляется по всем колонкам дерева. Значение по умолчанию — Пустая строка.
• ВключатьПодчиненные (необязательный, тип Булево). Определяет, будут ли участвовать в поиске строки подчиненных коллекций (если таковые имеются). Если Истина — строки подчиненных коллекций участвуют в поиске. Значение по умолчанию — Ложь.

Метод осуществляет поиск значения в дереве в указанных колонках коллекции строк дерева значений. Возвращает строку (тип СтрокаДереваЗначений), которая содержит искомое значение. Если значение не найдено, то возвращается значение Неопределено. Предназначен для поиска уникальных значений.

&НаКлиенте
Процедура НайтиСтрокуДереваЗначений(Команда)
    ЗаполнитьТабличноеПолеНаСервере();
    НайтиСтрокуДереваЗначенийНаСервере();
КонецПроцедуры

&НаСервере
Процедура НайтиСтрокуДереваЗначенийНаСервере()
    ДеревоЗначений = РеквизитФормыВЗначение("РеквизитДеревоЗначений");
    РезультатПоиска = ДеревоЗначений.Строки.Найти(
        ИскомоеЗначение,
        "ПерваяКолонка,ВтораяКолонка",
        Истина
    );
    Если РезультатПоиска <> Неопределено Тогда
        Сообщить(
            "Первая колонка: " + РезультатПоиска.ПерваяКолонка +
            ", Вторая колонка: " + РезультатПоиска.ВтораяКолонка
        );
    Иначе
        Сообщить("Ничего не найдено");
    КонецЕсли;
КонецПроцедуры

&НаСервере
Процедура ЗаполнитьТабличноеПолеНаСервере()
    Запрос = Новый Запрос();
    Запрос.Текст = 
        "ВЫБРАТЬ
        |    Номенклатура.Наименование КАК ПерваяКолонка,
        |    Номенклатура.Код КАК ВтораяКолонка
        |ИЗ
        |    Справочник.Номенклатура КАК Номенклатура
        |УПОРЯДОЧИТЬ ПО
        |    ПерваяКолонка ИЕРАРХИЯ";
    ДеревоЗначений = Запрос.Выполнить().Выгрузить(
        ОбходРезультатаЗапроса.ПоГруппировкамСИерархией
    );
    ЗначениеВРеквизитФормы(ДеревоЗначений, "РеквизитДеревоЗначений");
КонецПроцедуры

Поиск:
1С:Предприятие • Дерево значений • Иерархия • Коллекция • Таблица формы • Типы данных • Управляемая форма

Дерево значений — это универсальная коллекция 1С, которая позволяет хранить данные в иерархическом виде. Данная коллекция похожа на таблицу значений, но в дереве каждая строка может иметь подчиненные строки.

Поиск, сортировка и получение итогов могут выполняться как только по одному уровню иерархии, так и включая подчиненные строки.

В толстом клиенте нельзя передавать дерево значений с клиента на сервер. На тонком клиенте дерево значений не доступно.

Создание дерева значений

Создать новое дерево значений можно с помощью конструктора:

//создание дерева без колонок и строк
ДеревоТоваров = Новый ДеревоЗначений;

У дерева значений есть свойства Колонки и Строки. Для добавления новых строк сначала нужно добавить колонки дерева:

//добавление колонок в дерево значений
ДеревоТоваров.Колонки.Добавить(«Номенклатура»);
ДеревоТоваров.Колонки.Добавить(«Цена»);

Теперь через свойство Строки можно добавлять строки дерева:

//добавление новых строк
СтрДерева = ДеревоТоваров.Строки.Добавить();
СтрДерева.Номенклатура = «Монитор»;
СтрДерева.Цена = 10000;

СтрДерева= ДеревоТоваров.Строки.Добавить();
СтрДерева.Номенклатура = «Системный блок»;
СтрДерева.Цена = 30000;

Новые строки будут добавлены на первый уровень иерархии. Чтобы добавить к существующей строке подчиненные строки нужно обратиться к свойству Строки существующей строки дерева значений:

ПодчиненнаяСтрока = СтрДерева.Строки.Добавить();
ПодчиненнаяСтрока.Номенклатура = «Процессор»;
ПодчиненнаяСтрока.Цена = 10000;

ПодчиненнаяСтрока = СтрДерева.Строки.Добавить();
ПодчиненнаяСтрока.Номенклатура = «Оперативная память»;
ПодчиненнаяСтрока.Цена = 5000;

В результате у строки с номенклатурой «Системный блок» будет 2 подчиненных строки с процессором и оперативной памятью.

Рассмотрим другие операции с деревом значений:

//вставить новую строку в самое начало
СтрДерева = ДеревоТоваров.Строки.Вставить(0); //указываем индекс строки,
//куда ее нужно вставить
СтрДерева.Номенклатура = «Клавиатура»;
СтрДерева.Цена = 1000;

//к строкам можно обращаться через квадратные скобки
//в квадратных скобках указывается индекс строки
Сообщить(ДеревоТоваров.Строки[1].Номенклатура); //Монитор

//через квадратные скобки можно обращаться к колонкам дерева через имя колонки
СтрДерева[«Цена»] = 1500; //теперь Клавиатура стоит 1500

//можно через методы Установить и Получить
СтрДерева.Установить(1, 2000); //первым параметром передается индекс колонки
Сообщить(СтрДерева.Получить(1)); //2000

//с помощью метода Владелец из строки можно получить само дерево
СсылкаНаДерево = СтрДерева.Владелец(); //получаем само дерево

//через свойство Родитель у подчиненной строки можно получить родительскую строку
РодСтрока = ПодчиненнаяСтрока.Родитель;
Сообщить(РодСтрока.Номенклатура); // Монитор

Колонки дерева значений

Вся работа с колонками дерева значений осуществляется через свойство Колонки дерева. Колонки одинаковые для всех строк, включая подчиненные строки.

ДеревоЗаказов = Новый ДеревоЗначений;
//добавление новой колонки дерева значений
ДеревоЗаказов.Колонки.Добавить("Заказ");

//добавление типизированной колонки
ДеревоЗаказов.Колонки.Добавить("СуммаЗаказа", Новый ОписаниеТипов("Число"));

//проверка есть ли такая колонка
НайдКолДер = ДеревоЗаказов.Колонки.Найти("Заказ");
Если НайдКолДер = Неопределено Тогда
	//нет такой колонки
Иначе
	//НайдКолДер- ссылка на колонку дерева
КонецЕсли;	

//количество колонок
Колво = ДеревоЗаказов.Колонки.Количество();

//перебор всех колонок
Для Каждого КолДер Из ДеревоЗаказов.Колонки Цикл
	//у колонки есть свойства Имя, ТипЗначения, Заголовок и Ширина
	Сообщить(КолДер.Имя);
	Сообщить(КолДер.ТипЗначения);
	Сообщить(КолДер.Заголовок);
	Сообщить(КолДер.Ширина);
	//Заголовок и Ширина используются если дерево отображается на форме
КонецЦикла;	

//удаление одной колонки
ДеревоЗаказов.Колонки.Удалить(0); //удаляем первую строку

//удаление всех колонок
ДеревоЗаказов.Колонки.Очистить();

Итоги по дереву значений

Для получения итога по числовой колонке дерева значений можно использовать метод Итог:

ДеревоСумм = Новый ДеревоЗначений;
ДеревоСумм.Колонки.Добавить(«Сумма»);

//добавим 2 строки на первый уровень
СтрДерева = ДеревоСумм.Строки.Добавить();
СтрДерева.Сумма = 100;

СтрДерева = ДеревоСумм.Строки.Добавить();
СтрДерева.Сумма = 200;

//и 2 подчиненные строки у второй строки
ПодчиненнаяСтрока = СтрДерева.Строки.Добавить();
ПодчиненнаяСтрока.Сумма = 50;

ПодчиненнаяСтрока = СтрДерева.Строки.Добавить();
ПодчиненнаяСтрока.Сумма = 60;

//получим итог по строкам первого уровня
Сообщить(ДеревоСумм.Строки.Итог(«Сумма», Ложь)); //300

//чтобы получить итог по всем строкам, включая подчиненные
//нужно вторым параметром передать Истина
Сообщить(ДеревоСумм.Строки.Итог(«Сумма», Истина)); //410

Поиск по дереву значений

Поиск по дереву значений выполняется с помощью методов Найти и НайтиСтроки. Метод Найти используется для поиска уникального значения, то есть если искомое значение встречается в дереве несколько раз, то метод вернет первую найденную строку. Метод НайтиСтроки вернет все подходящие под условие строки. По умолчанию поиск выполняется только по одному уровню иерархии. Но если передать последним параметром Истина, то поиск будет выполнен также и в подчиненных строках.

ДеревоТоваров = Новый ДеревоЗначений;
ДеревоТоваров.Колонки.Добавить(«Товар»);

//добавим 3 строки на первый уровень
СтрДерева = ДеревоТоваров.Строки.Добавить();
СтрДерева.Товар = «Монитор»;

СтрДерева = ДеревоТоваров.Строки.Добавить();
СтрДерева.Товар = «Монитор»;

СтрДерева = ДеревоТоваров.Строки.Добавить();
СтрДерева.Товар = «Системный блок»;

//и 2 подчиненные строки у третьей строки
ПодчиненнаяСтрока = СтрДерева.Строки.Добавить();
ПодчиненнаяСтрока.Товар = «Процессор»;

ПодчиненнаяСтрока = СтрДерева.Строки.Добавить();
ПодчиненнаяСтрока.Товар = «Диск»;

//первый параметр значение поиска
//второй — колонка дерева для поиска
НайдСтр = ДеревоТоваров.Строки.Найти(«Монитор», «Товар», Ложь);
//вернет первую строку

НайдСтр = ДеревоТоваров.Строки.Найти(«Диск», «Товар», Ложь);
//вернет Неопределено, строка не найдена

НайдСтр = ДеревоТоваров.Строки.Найти(«Диск», «Товар», Истина);
//вернет подчиненную строку

//параметром передается структура
//ключ — колонка дерева для поиска
//значение — значение поиска
//можно указать несколько ключей, поиск будет выполняться по всем совпадениям
Отбор = Новый Структура(«Товар», «Монитор»);
НС = ДеревоТоваров.Строки.НайтиСтроки(Отбор, Ложь);
//вернет массив с двумя строками

Отбор = Новый Структура(«Товар», «Диск»);
НС = ДеревоТоваров.Строки.НайтиСтроки(Отбор, Ложь);
//вернет пустой массив

НС = ДеревоТоваров.Строки.НайтиСтроки(Отбор, Истина);
//вернет массив с одной подчиненной строкой

Удаление строк из дерева значений

Для удаления строк из дерева значений используются методы Удалить и Очистить. Метод Удалить удаляет строку, включая все подчиненные ей строки. Метод Очистить удаляет все строки из дерева значений.

ДеревоТоваров = Новый ДеревоЗначений;
ДеревоТоваров.Колонки.Добавить(«Товар»);

//добавим 3 строки на первый уровень
ПерваяСтрока = ДеревоТоваров.Строки.Добавить();
ПерваяСтрока.Товар = «Монитор»;

ВтораяСтрока = ДеревоТоваров.Строки.Добавить();
ВтораяСтрока.Товар = «Монитор»;

ТретьяСтрока = ДеревоТоваров.Строки.Добавить();
ТретьяСтрока.Товар = «Системный блок»;

//и 2 подчиненные строки у третьей строки
ПодчиненнаяСтрока = ТретьяСтрока.Строки.Добавить();
ПодчиненнаяСтрока.Товар = «Процессор»;

ПодчиненнаяСтрока = ТретьяСтрока.Строки.Добавить();
ПодчиненнаяСтрока.Товар = «Диск»;

//удалим строку с системным блоком:
ДеревоТоваров.Строки.Удалить(ТретьяСтрока);

//удалим строку с первым монитором по индексу
ДеревоТоваров.Строки.Удалить(0);

//удалим все строки дерева
ДеревоТоваров.Строки.Очистить();

При удалении нескольких строк из дерева значений по условию нужно воспользоваться тем же способом, который был рассмотрен в статье про таблицу значений.

Сортировка дерева значений

Для сортировки строк в дереве значений используется метод Сортировать. В зависимости от второго параметра сортировка будет выполняться только по одному уровню иерархии или включая подчиненные строки.

ДеревоТоваров = Новый ДеревоЗначений;
ДеревоТоваров.Колонки.Добавить(«Количество»);

//добавим 3 строки на первый уровень
ПерваяСтрока = ДеревоТоваров.Строки.Добавить();
ПерваяСтрока.Количество = «2»;

ВтораяСтрока = ДеревоТоваров.Строки.Добавить();
ВтораяСтрока.Количество = «1»;

ТретьяСтрока = ДеревоТоваров.Строки.Добавить();
ТретьяСтрока.Количество = «3»;

//и 3 подчиненные строки у третьей строки
ПодчиненнаяСтрока = ТретьяСтрока.Строки.Добавить();
ПодчиненнаяСтрока.Количество = «20»;

ПодчиненнаяСтрока = ТретьяСтрока.Строки.Добавить();
ПодчиненнаяСтрока.Количество = «10»;

ПодчиненнаяСтрока = ТретьяСтрока.Строки.Добавить();
ПодчиненнаяСтрока.Количество = «30»;

//отсортируем по возрастанию
ДеревоТоваров.Строки.Сортировать(«Количество», Ложь);
//так как второй параметр равен Ложь, то подчиненные строки
//не были отсортированы

//отсортируем по убыванию, включая подчиненные строки
//чтобы отсортировать по убыванию нужно после имени колонки указать Убыв
ДеревоТоваров.Строки.Сортировать(«Количество Убыв», Истина);

Создание копии дерева значений

Для создания полной копии дерева значений можно воспользоваться методом Скопировать.

ДеревоТоваров = Новый ДеревоЗначений;
ДеревоТоваров.Колонки.Добавить(«Количество»);

//добавим 3 строки на первый уровень
ПерваяСтрока = ДеревоТоваров.Строки.Добавить();
ПерваяСтрока.Количество = «2»;

ВтораяСтрока = ДеревоТоваров.Строки.Добавить();
ВтораяСтрока.Количество = «1»;

ТретьяСтрока = ДеревоТоваров.Строки.Добавить();
ТретьяСтрока.Количество = «3»;

//и 3 подчиненные строки у третьей строки
ПодчиненнаяСтрока = ТретьяСтрока.Строки.Добавить();
ПодчиненнаяСтрока.Количество = «20»;

ПодчиненнаяСтрока = ТретьяСтрока.Строки.Добавить();
ПодчиненнаяСтрока.Количество = «10»;

ПодчиненнаяСтрока = ТретьяСтрока.Строки.Добавить();
ПодчиненнаяСтрока.Количество = «30»;

// создание полной копии дерева, со всеми строками и колонками
КопияДерева = ДеревоТоваров.Скопировать();

Важно понимать, что в памяти будет создано новое дерево значений и в переменной КопияДерева будет ссылка на него. Если в копии дерева менять значения, то в первоначальном дереве не будет этих изменений.

Рекурсивный обход дерева значений

Обойти дерево значений можно с помощью цикла Для Каждого. Если нужно обойти все дерево, включая подчиненные строки, то можно использовать рекурсию:

&НаСервере
Процедура Команда1НаСервере()
		
	ДеревоТоваров = Новый ДеревоЗначений;
	ДеревоТоваров.Колонки.Добавить("Количество");
	
	//добавим 3 строки на первый уровень
	ПерваяСтрока = ДеревоТоваров.Строки.Добавить();
	ПерваяСтрока.Количество = "2";
	
	ВтораяСтрока = ДеревоТоваров.Строки.Добавить();
	ВтораяСтрока.Количество = "1";
	
	ТретьяСтрока = ДеревоТоваров.Строки.Добавить();
	ТретьяСтрока.Количество = "3";
	
	//и 3 подчиненные строки у третьей строки
	ПодчиненнаяСтрока = ТретьяСтрока.Строки.Добавить();
	ПодчиненнаяСтрока.Количество = "20";
	
	ПодчиненнаяСтрока = ТретьяСтрока.Строки.Добавить();
	ПодчиненнаяСтрока.Количество = "10";
	
	ПодчиненнаяСтрока = ТретьяСтрока.Строки.Добавить();
	ПодчиненнаяСтрока.Количество = "30";
	
	//обход только строк верхнего уровня
	Для Каждого СтрДер Из ДеревоТоваров.Строки Цикл
		Сообщить(СтрДер.Количество);
	КонецЦикла;	
	
	//обход всего дерева значений
	РекурсивныйОбходДереваЗначений(ДеревоТоваров);
КонецПроцедуры

&НаСервере
Процедура РекурсивныйОбходДереваЗначений(ДеревоЗначенийИлиСтрокаДерева)
	Для Каждого СтрДер  Из ДеревоЗначенийИлиСтрокаДерева.Строки Цикл
		Сообщить(СтрДер.Количество);
		//передаем строку дерева в эту же процедуру
		//чтобы обойти все ее подчиненные строки
		РекурсивныйОбходДереваЗначений(СтрДер);
	КонецЦикла;	
КонецПроцедуры

Смотрите также:
Электронный учебник по по программированию в 1С
Рекомендации по изучению программирования 1С с нуля
Программное решение для сдачи и подготовки к экзаменам
Программирование в 1С 8.3 с нуля — краткий самоучитель
Комплексная подготовка программистов 1С:Предприятие 8.2
Сайты с уроками программирования и со справочниками
Youtube-каналы с уроками программирования
Сайты для обучения программированию
Лекции и уроки